cc = meson.get_compiler('c')

iridium_sources = [
  'main.c',
  'iridium-note.c',
  'iridium-note-row.c',
  'iridium-tag.c',
  'iridium-tag-row.c',
  'iridium-signin-dialog.c',
  'iridium-standard-file.c',
  'iridium-storage.c',
  'iridium-markdown.c',
  'iridium-window.c',
]

iridium_deps = [
  dependency('gio-2.0', version: '>= 2.48'),
  dependency('gtk+-3.0', version: '>= 3.18'),
  dependency('gtksourceview-3.0', version: '>= 3.18'),
  dependency('json-glib-1.0', version: '>= 1.1.2'),
  dependency('libsecret-1', version: '>= 0.18.4'),
  dependency('libsoup-2.4', version: '>= 2.52.2'),
  dependency('nettle', version: '>= 3.2'),
  dependency('webkit2gtk-4.0', version: '>= 2.20.2'),
  declare_dependency(
    dependencies: cc.find_library('markdown'),
  ),
]

if not cc.has_header('mkdio.h')
  error('Cannot find mkdio.h')
endif

gnome = import('gnome')

iridium_sources += gnome.compile_resources('iridium-resources',
  'iridium.gresource.xml',
  c_name: 'iridium'
)

executable('iridium', iridium_sources,
  dependencies: iridium_deps,
  install: true,
)